pro plot_sst,infileSST

binarydata=bytarr(1440,720)
sst = fltarr(1440,720)
scale  =  0.15
offset = -3.0

;determine if file exists
exist=File_Test(infileSST)
if (exist ne 1) then begin
  print, 'no SST file by that name', infileSST
  return
endif


openr,lun,infileSST, error=err, /get_lun,/compress    ;compress keyword allows reading of gzip file, remove if data already unzipped
if (err gt 0) then begin
  print, 'ERROR OPENING FILE: ', infileSST
  return
endif

readu,lun,binarydata
free_lun, lun

sst=float(binarydata)*scale+offset
;add a duplicate column to eliminate line down middle
sst=[sst,sst[0,*]]

lat = findgen(720)/4.-89.875
lon = [findgen(720)/4.,findgen(720)/4.-179.875]
lon = [lon,lon[0]]

map_set, 0.,0.,/cylindrical
loadct,39,/silent
contour, sst, lon, lat,/isotropic,/overplot, background=255,/cell_fill,levels=-5.+findgen(40)
map_continents,color=0,fill_continents=1
map_grid,color=0,latdel=15.,londel=15.
colorbar, vmin=-5.,vmax=34.,cmin=1,cmax=254,title='SST ('+string("232B)+'C)',position=[0.3,0.1,0.7,0.15]

end